%{
extern void lexerror();
int strcnt = 0;
#define STRSIZE 80  
char string[STRSIZE +1] = {0}; 
extern char *putstring();
%}
%start STR COMM
%%
<INITIAL>"+" return (ADDOP);
<INITIAL>"-" return (SUBOP);
<INITIAL>"*" return (MULOP);
<INITIAL>"/" return (DIVOP);
<INITIAL>"=" return (ASGNOP);
<INITIAL>"<"  return (LTOP);
<INITIAL>"{" return (LC);
<INITIAL>"}" return (RC);
<INITIAL>"(" return (LP);
<INITIAL>")" return (RP);
<INITIAL>";" return (SC);
<INITIAL>\" {
               strcnt = 0;
               BEGIN STR;
             }
<INITIAL>"/*" BEGIN COMM;
<INITIAL>while return(WHILE);
<INITIAL>printstr return(PRINTSTR);
<INITIAL>printvar return(PRINTVAR);
<INITIAL>x[0-9]+ { sscanf ( &yytext[1], "%d", &yylval.xnum);
                   if (yylval.xnum > VAR_LEN)
                      lexerror("variable invalid:  ", yytext,1); 
                   return (VAR); }
<INITIAL>[0-9]+\.[0-9]*|[0-9]+ { sscanf (yytext,"%lf", &yylval.floating); 
                      return (NUMBER); }
<INITIAL>[ \t\n] ;
<INITIAL>[a-zA-Z0-9]+ lexerror ("word invalid:  ", yytext, 0);
<INITIAL>. lexerror("character invalid:  ", yytext, 0);
<STR>\" { if ( strcnt >= STRSIZE ) {
              string[STRSIZE] = '\0';
              strcnt = STRSIZE;
              lexerror ( "string too long:  ", string, 0);
          }
          string[strcnt] = '\0';
          yylval.str = putstring (string);
          BEGIN INITIAL;
          return (STRING);
        }
<STR>\\n { if ( strcnt < STRSIZE )
            string[strcnt++] = '\n';
         }
<STR>\n { string[strcnt] = '\0';
          lexerror ("string not closed:  ", string, 0); 
          yylval.str = putstring (string);
          BEGIN INITIAL;
          return (STRING);
        }
<STR>.  { if ( strcnt < STRSIZE )
            string[strcnt++] = yytext[0];
        }
<COMM>"*/"  BEGIN INITIAL;
<COMM>\n  ;
<COMM>.   ;
%%
void lexerror ( char *s0, char *s1, int n )
{
    fprintf(stderr, "%s%s", s0, s1);
    if (n) exit(0);
}